const std = @import("std");
const ProtocolError = @import("../main.zig").ProtocolError;
const enum_from_int = @import("../main.zig").enum_from_int;
const ByteArrayList = std.ArrayList(u8);

const ReadyForQuery = @This();
pub const Tag: u8 = 'Z';

const TransactionStatus = enum(u8) {
    idle = 'I',
    transaction = 'T',
    err = 'E',
};

transaction_status: TransactionStatus,

pub fn read(allocator: std.mem.Allocator, b: []const u8) !ReadyForQuery {
    _ = allocator;
    if (b.len != 1) return ProtocolError.InvalidMessageLength;
    return .{ .transaction_status = enum_from_int(TransactionStatus, b[0]) orelse return ProtocolError.InvalidTransactionStatus };
}
pub fn write(self: ReadyForQuery, allocator: std.mem.Allocator, stream_writer: anytype) !void {
    _ = allocator;
    try stream_writer.writeByte(Tag);
    try stream_writer.writeIntBig(u32, 5);
    try stream_writer.writeByte(@intFromEnum(self.transaction_status));
}
pub fn deinit(_: *ReadyForQuery, _: std.mem.Allocator) void {}

test "round trip" {
    const allocator = std.testing.allocator;
    var sm = ReadyForQuery{
        .transaction_status = TransactionStatus.idle,
    };
    defer sm.deinit(allocator);

    var bal = ByteArrayList.init(allocator);
    defer bal.deinit();
    try sm.write(allocator, bal.writer());

    var fbs = std.io.fixedBufferStream(bal.items);
    var reader = fbs.reader();
    const tag = try reader.readByte();
    try std.testing.expectEqual(Tag, tag);
    const len = try reader.readIntBig(u32);
    const buf = try allocator.alloc(u8, len - 4);
    defer allocator.free(buf);
    try reader.readNoEof(buf);
    var sm2 = try ReadyForQuery.read(allocator, buf);
    defer sm2.deinit(allocator);

    try std.testing.expectEqual(TransactionStatus.idle, sm2.transaction_status);
}